Ce logiciel Windows permet de créer des sortes de macros, notamment déclenchées en détectant des événements clavier ou souris.

Des raccourcis pratiques pour insérer rapidement des infos récurrentes :

::j@::j-----@-------
::j04::04.37.xx.xx:xx
::j06::06.49.xx.xx.xx 

Même principe, pour insérer la date au format YYYYMMDD en tapant simplement dat :

::dat::
	Send, %A_YYYY%%A_MM%%A_DD% 
Return 

Tout un tas de symboles divers. La liste complète se trouve ici. :

::*feu*::🔥
::*fire*::🔥
::*metro*::🚇
::*métro*::🚇
::*tel*::📞
::*téléphone*::📞
::*train*::🚋
::*voiture*::🚘

Lancer ou afficher la fenêtre

Le code suivant permet de lancer Firefox avec le raccourci Win+f, ou bien d'activer la fenêtre si Firefox est déjà ouvert.

#f::
	IfWinExist, ahk_exe firefox.exe
	{
		WinActivate
	}
	else
	{
		Run, C:\Program Files (x86)\Mozilla Firefox\firefox.exe
		WinActivate
	}
Return

Modifier la visibilité des onglets

Le code suivant permet de mapper sur la touche F1 le raccourci Ctrl+Shift+o permettant de basculer l'affichage de la barre d'onglets verticale (cf. Firefox)

#IfWinActive ahk_exe firefox.exe
F1::
	SendInput, ^+o
Return

Traiter ses courriels au clavier

Le code suivant permet l'appui d'une simple touche pour traiter ses courriels :

• a pour archiver
• d pour supprimer
• f pour faire suivre un courriel
• r pour répondre à tou·te·s
• Shift+r pour répondre au seul expéditeur

L'archivage est en fait une action rapide qui a pour raccourci Ctrl+Shift+9 qui est remappé sur a. Par ailleurs, le déplacement entre les courriels se fait à l'aide de t et s (reprenant ainsi les commandes « à la vim », mais adaptées au bépo).

#IfWinActive ahk_exe outlook.exe

; Fonction qui s'assure que le focus est sur la liste des courriels
; de façon à ce que les raccourcis qui suivent ne s'exécutent pas lors
; de la composition d'un courriel…

AuBonEndroit()
{
	ControlGetFocus, vControl, A
	if (vControl = "OutlookGrid1" or vControl = "OutlookGrid2")
	{
	return True
	}
	else
	{
	return False
	}
}

#If AuBonEndroit()

f::Send, ^f ; forward
t::Send, {Down}
s::Send, {Up}
a::Send, ^+9 ; Action rapide archive
d::Send, ^d ; suppression mail
r::Send, ^+r ; répondre à tous
+r::Send, ^r ; répondre